Introduce rabbitmq-diagnostics erlang_version

deps/rabbitmq_cli/lib/rabbitmq/cli/diagnostics/commands/erlang_version_command.ex

@@ -0,0 +1,52 @@
+## The contents of this file are subject to the Mozilla Public License
+## Version 1.1 (the "License"); you may not use this file except in
+## compliance with the License. You may obtain a copy of the License
+## at http://www.mozilla.org/MPL/
+##
+## Software distributed under the License is distributed on an "AS IS"
+## basis, WITHOUT WARRANTY OF ANY KIND, either express or implied. See
+## the License for the specific language governing rights and
+## limitations under the License.
+##
+## The Original Code is RabbitMQ.
+##
+## The Initial Developer of the Original Code is GoPivotal, Inc.
+## Copyright (c) 2007-2017 Pivotal Software, Inc.  All rights reserved.
+
+
+defmodule RabbitMQ.CLI.Diagnostics.Commands.ErlangVersionCommand do
+  @behaviour RabbitMQ.CLI.CommandBehaviour
+
+  def merge_defaults(args, opts) do
+    {args, Map.merge(%{details: false}, opts)}
+  end
+
+  def validate(args, _) when length(args) > 0 do
+    {:validation_failure, :too_many_args}
+  end
+  def validate(_, _), do: :ok
+
+  def switches(), do: [details: :boolean]
+
+  def usage, do: "erlang_version"
+
+  def run([], %{node: node_name, timeout: timeout, details: details}) do
+    case details do
+      true ->
+        :rabbit_misc.rpc_call(node_name, :rabbit_misc, :otp_system_version, [], timeout)
+      false ->
+        :rabbit_misc.rpc_call(node_name, :rabbit_misc, :platform_and_version, [], timeout)
+    end
+  end
+
+  def output(result, _options) when is_list(result) do
+    {:ok, result}
+  end
+  use RabbitMQ.CLI.DefaultOutput
+
+  def banner([], %{node: node_name}) do
+    "Asking node #{node_name} for its Erlang/OTP version..."
+  end
+
+  def formatter(), do: RabbitMQ.CLI.Formatters.String
+end

deps/rabbitmq_cli/test/diagnostics/erlang_version_command_test.exs

@@ -0,0 +1,73 @@
+## The contents of this file are subject to the Mozilla Public License
+## Version 1.1 (the "License"); you may not use this file except in
+## compliance with the License. You may obtain a copy of the License
+## at http://www.mozilla.org/MPL/
+##
+## Software distributed under the License is distributed on an "AS IS"
+## basis, WITHOUT WARRANTY OF ANY KIND, either express or implied. See
+## the License for the specific language governing rights and
+## limitations under the License.
+##
+## The Original Code is RabbitMQ.
+##
+## The Initial Developer of the Original Code is GoPivotal, Inc.
+## Copyright (c) 2007-2017 Pivotal Software, Inc.  All rights reserved.
+
+
+defmodule ErlangVersionCommandTest do
+  use ExUnit.Case
+  import TestHelper
+
+  @command RabbitMQ.CLI.Diagnostics.Commands.ErlangVersionCommand
+
+  setup_all do
+    RabbitMQ.CLI.Core.Distribution.start()
+
+    :ok
+  end
+
+  setup context do
+    {:ok, opts: %{
+        node: get_rabbit_hostname(),
+        timeout: context[:test_timeout] || 30000,
+        details: false
+      }}
+  end
+
+  test "merge_defaults: defaults to abbreviated output" do
+    assert @command.merge_defaults([], %{}) == {[], %{details: false}}
+  end
+
+  test "validate: treats positional arguments as a failure" do
+    assert @command.validate(["extra-arg"], %{}) == {:validation_failure, :too_many_args}
+  end
+
+  test "validate: treats empty positional arguments and default switches as a success" do
+    assert @command.validate([], %{}) == :ok
+  end
+
+  test "validate: treats empty positional arguments and --details as a success" do
+    assert @command.validate([], %{details: true}) == :ok
+  end
+
+  @tag test_timeout: 0
+  test "run: targeting an unreachable node throws a badrpc", context do
+    target = :jake@thedog
+
+    opts = %{node: target, details: false}
+    assert @command.run([], Map.merge(context[:opts], opts)) == {:badrpc, :nodedown}
+  end
+
+  test "run: returns Erlang/OTP version on the target node", context do
+    res = @command.run([], context[:opts])
+    # assert that we have a list of characters
+    assert length(res) > 0 and :io_lib.char_list(res)
+  end
+
+  test "run with --details: returns Erlang/OTP version on the target node", context do
+    IO.inspect Map.merge(%{details: true}, context[:opts])
+    res = @command.run([], Map.merge(%{details: true}, context[:opts]))
+    # assert that we have a list of characters
+    assert length(res) > 0 and :io_lib.char_list(res)
+  end
+end